**********************
* TUBE PSpice MODELS *
**********************
*
* Basic PSpice model by Norman Koren (Glass Audio 5/96, p. 22)
* Additional tube models by Jukka Tolonen
*

* 12AT7/ECC81 model, data based on "The Audio Designer's Tube Register"
* Optimized for operating point Ip=5.0mA, Vp=100V.
* 
.SUBCKT ECC81 1 2 3	; P G C
+ PARAMS: MU=60  EX=1.29 KG1=527 KP=255 KVB=325 RGI=2000
+ CCG=2.9P CGP=2.2P CCP=1.0P 
* ADD 0.7pF TO ADJACENT PINS, 0.5pF TO OTHERS
E1  7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1  1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWERS
C1  2 3 {CCG} ; CATHODE-GRID
C2  2 1 {CGP} ; CRID-PLATE
C3  1 3 {CCP} ; CATHODE-PLATE
D3  5 3 DX    ; FOR GRID CURRENT
R1  2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10P TT=1N)
.ENDS

* 6922/E88CC model, data based on a graph in GA 2/94, p. 6,
* thus not very accurate.
*
.SUBCKT 6922 1 2 3	; P G C
+ PARAMS: MU=32  EX=1.61 KG1=406 KP=357 KVB=486 RGI=2000
+ CCG=2.3P CGP=2.1P CCP=0.7P 
E1  7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1  1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWERS
C1  2 3 {CCG} ; CATHODE-GRID
C2  2 1 {CGP} ; CRID-PLATE
C3  1 3 {CCP} ; CATHODE-PLATE
D3  5 3 DX    ; FOR GRID CURRENT
R1  2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10P TT=1N)
.ENDS